Visual BasicNullReferenceException中的那个与C#中的没有什么不同。毕竟，它们都报告了两种语言都基于的 .Net Framework 中定义的相同异常。可能是 Visual Basic 独有的原因很少（可能只有一个）。

此答案将使用 Visual Basic 术语、语法和上下文。使用的示例取自 Stack Overflow 上的大量旧问题。通过这种方式，它的相关性被最大化，使用 帖子中经常出现的那种情况。还为可能需要它们的人附加了一些更多的解释。很可能在这里找到与您类似的示例。

成绩：

1. 这是一个概念性的答案：没有可以复制并粘贴到项目中的代码。这一切都是为了帮助您了解导致 NullReferenceExceptionNRE 的原因、如何找到它、如何修复它以及如何避免它。NRE 可能有很多原因，所以不要指望在这里找到所有原因。
2. 这些示例（来自 Stack Overflow 帖子）并不总是显示做某事的最佳方式。
3. 通常我们会使用最简单的解决方案。

基本含义

消息“对象引用未设置为对象的实例” 表示您正在尝试使用尚未初始化的对象。这可以缩小到以下原因之一：

• 在您的代码中，您已声明了一个对象变量，但尚未对其进行初始化（您尚未实例化或“实例化”它）
• 假定初始化对象的代码中的某些内容没有。
• 也许另一段代码使仍在使用中的对象过早失效

寻找原因

假设问题是一个对象引用，即Nothing，答案是检查对象以找出问题所在，然后确定它未初始化的原因。将鼠标光标悬停在变量上，Visual Studio (VS) 将向您显示它们的值 - 罪魁祸首将是Nothing.

您还应该从代码的相关部分中删除任何 Try/Catch 块，尤其是那些具有空 Catch 块的部分。这将导致您的代码在尝试使用Nothing. 这就是您想要的，因为这将查明问题的确切位置，从而使您能够确定是哪个对象导致了它。

显示MsgBox的 Catch 块中Error en...的一个非常无用。这种捕获异常的方法也会在 Stack Overflow 上引发非常糟糕的问题，因为您无法描述实际的异常、导致它的对象是什么，甚至无法描述它发生的代码行。

您还可以使用窗口Variables Locales（Debug -> Windows -> Locals）来检查您的对象。

一旦您知道问题是什么以及问题出在哪里，通常比添加新问题更容易解决并且更快。

也可以看看：

• 断点
• MSDN：如何：使用 Try/Catch 块捕获异常
• MSDN：异常的最佳实践

示例和解决方案

类对象/创建实例

Dim reg As Registradora
...
TextBox1.Text = reg.Cantidad         ' NRE

问题是Dim它没有创建类型的对象Registradora；它只是声明了reg该类型的命名变量。声明对象变量和创建它的实例是两件不同的事情。

解决方案

运算符New是声明对象时通常用于创建实例的运算符：

Dim reg As New Registradora        ' [New] crea la instancia, invoca el constructor

' Otra forma mas larga y explícita:
Dim reg As Registradora = New Registradora        

稍后应创建实例时：

Private reg As Registradora         ' Declaración
  ...
reg = New Registradora()            ' Creamos la instancia

注意：不要在过程中再次使用Dim，包括构造函数（Sub New）：

Private reg As Registradora
'...

Public Sub New()
   '...
   Dim reg As New Registradora
End Sub

这将创建一个局部变量, reg，它只存在于这个（子）上下文中。reg您作为模块拥有的变量ámbito以及您将在其他任何地方使用的变量仍然保留为Nothing.

忘记操作员New是引发NullReferenceExceptionsStack Overflow 问题的第一大原因。

Visual Basic 试图通过重复使用来使过程清晰 New： 使用运算符New创建一个新对象并调用 Sub New- 构造函数 - 您的对象可以在其中执行任何其他初始化。

为了清楚起见，Dim(o Private) 只是声明了一个变量及其Type( type )。变量的范围——它是否存在于整个模块/类或者它是否是一个过程的局部变量——取决于它的声明位置。Private | Friend | Public定义访问级别，而不是其Scope。

有关更多信息，请参阅：

• 新运营商
• Visual Basic 中的作用域
• Visual Basic 中的访问级别
• 值类型和引用类型

---

数组

数组也必须实例化：

Private arr as String()

这个数组只是被声明了，没有被创建。有几种初始化数组的方法：

Private arr as String() = New String(10){}
' or
Private arr() As String = New String(10){}

' Para un array local (en un procedimiento) y usando 'Option Infer':
Dim arr = New String(10) {}

注意：从 VS 2010 开始，当使用文字 and 初始化本地数组时Option Infer，元素As <Type>andNew是可选的：

Dim myDbl As Double() = {1.5, 2, 9.9, 18, 3.14}
Dim myDbl = New Double() {1.5, 2, 9.9, 18, 3.14}
Dim myDbl() = {1.5, 2, 9.9, 18, 3.14}

数组大小的类型和大小是从分配的数据中推断出来的。类/模块级声明仍然As <Type>需要Option Strict：

Private misDoubles As Double() = {1.5, 2, 9.9, 18, 3.14}

示例：类对象数组

Dim arrFoo(5) As Foo

For i As Integer = 0 To arrFoo.Count - 1
   arrFoo(i).Bar = i * 10       ' Excepción
Next

数组已创建，但其中的类型对象尚未创建Foo。

解决方案

For i As Integer = 0 To arrFoo.Count - 1
    arrFoo(i) = New Foo()         ' Crear instancia de Foo
    arrFoo(i).Bar = i * 10
Next

使用 oneList(Of T)将使没有有效对象的元素变得非常困难：

Dim FooList As New List(Of Foo)     ' Lista creadad, pero está vacia
Dim f As Foo                        ' Variable temporal para el bucle
For i As Integer = 0 To 5
    f = New Foo()                    ' Instancia de Foo creada
    f.Bar =  i * 10
    FooList.Add(f)                   ' objeto de tipo Foo añadido a la lista
Next

有关更多信息，请参阅：

• 期权推断语句
• Visual Basic 中的作用域
• Visual Basic 中的数组

---

列表和集合

.NET 中的集合（其中有很多种 - 列表、字典等）也必须实例化或创建。

Private miLista As List(Of String)
..
miLista.Add("prueba")           ' NullReference

由于相同的原因，您会得到相同的异常——它miLista只是被声明了，但没有创建实例。解决方法是一样的：

miLista = New List(Of String)

' O crear la instancia al declararla:
Private miLista As New List(Of String)

一个常见的错误是使用Type集合类型（）的类：

Public Class Foo
    Private barList As List(Of Bar)

    Friend Function BarCount As Integer
        Return barList.Count
    End Function

    Friend Sub AddItem(newBar As Bar)
        If barList.Contains(newBar) = False Then
            barList.Add(newBar)
        End If
    End Function

这两个过程都会导致 NRE，因为barList它只是被声明的，没有被实例化。创建一个实例Foo不会同时创建一个 barList内部实例。也许目的是在构造函数中做到这一点：

Public Sub New         ' Constructor
    ' Cosas que hacer cuando se crea un nuevo Foo...
    barList = New List(Of Bar)
End Sub

和以前一样，这是不正确的：

Public Sub New()
    ' Crea otra barList local a este procedimiento
     Dim barList As New List(Of Bar)
End Sub

有关详细信息，请参阅类List<T>。

---

数据提供者对象

使用数据库意味着 NullReferenceException 有很多机会，因为可以同时使用许多对象 ( , Command, Connection, Transaction, Dataset.... )。 注意：你使用什么数据提供者并不重要——MySQL、SQL Server、OleDB 等。——概念是一样的。DataTableDataRows

示例 1

Dim da As OleDbDataAdapter
Dim ds As DataSet
Dim MaxRows As Integer

con.Open()
Dim sql = "SELECT * FROM tblfoobar_List"
da = New OleDbDataAdapter(sql, con)
da.Fill(ds, "foobar")
con.Close()

MaxRows = ds.Tables("foobar").Rows.Count      ' Error

和以前一样，已经声明了数据集ds，但从未创建过它的实例。他DataAdapter填充一个DataSet已经存在的，而不是创造一个。在这种情况下，由于它ds是一个局部变量，IDE 会警告您可能会发生这种情况：

当在模块/类级别声明为变量时con，编译器无法判断对象是否是由自下而上的过程创建的。不要忽视警告。

解决方案

Dim ds As New DataSet

示例 2

ds = New DataSet
da = New OleDBDataAdapter(sql, con)
da.Fill(ds, "Empleados")

txtID.Text = ds.Tables("Empleado").Rows(0).Item(1)
txtID.Name = ds.Tables("Empleado").Rows(0).Item(2)

错字是这里的问题：Empleados-> Empleado。没有DataTable一个叫做“员工”的人，所以一个人NullReferenceException试图访问它。另一个潜在的问题是假设它们将存在Items，当 SQL 查询包含 WHERE 子句时，这可能不是真的。

解决方案

由于示例中只使用了一个表，因此使用Tables(0)将避免拼写错误。浏览Rows.Count也可以帮助：

If ds.Tables(0).Rows.Count > 0 Then
    txtID.Text = ds.Tables(0).Rows(0).Item(1)
    txtID.Name = ds.Tables(0).Rows(0).Item(2)
End If

Fill是一个返回Rows受影响行数的函数（），也可以检查：

If da.Fill(ds, "Empleados") > 0 Then...

示例 3

Dim da As New OleDb.OleDbDataAdapter("SELECT TICKET.TICKET_NO,
        TICKET.CUSTOMER_ID, ... FROM TICKET_RESERVATION AS TICKET INNER JOIN
        FLIGHT_DETAILS AS FLIGHT ... WHERE [TICKET.TICKET_NO]= ...", con)
Dim ds As New DataSet
da.Fill(ds)

If ds.Tables("TICKET_RESERVATION").Rows.Count > 0 Then

将DataAdapter提供TableNames如上例所示，但不解析数据库表名。结果，它ds.Tables("TICKET_RESERVATION")引用了一个不存在的表。

解决方法是一样的，通过索引引用表：

If ds.Tables(0).Rows.Count > 0 Then

另请参见DataTable 类。

---

对象路径（Object Paths）/嵌套（Nested）

If myFoo.Bar.Items IsNot Nothing Then
   ...

代码只是在测试ItemswhilemyFoo也Bar可能是Nothing. 解决方案是一次尝试整个链或对象的真正：

If (myFoo IsNot Nothing) AndAlso
    (myFoo.Bar IsNot Nothing) AndAlso
    (myFoo.Bar.Items IsNot Nothing) Then
    ....

AndAlso这很重要。一旦满足第一个条件，后续测试将不会运行False。这允许代码安全地逐级检查对象，myFoo.Bar仅在确定对象myFoo有效之后（并且如果）进行评估。处理复杂对象时，对象链或路径可能会变得很长：

myBase.myNodes(3).Layer.SubLayer.Foo.Files.Add("somefilename")

也不能引用空对象下面的任何内容。这也适用于控件：

myWebBrowser.Document.GetElementById("formfld1").InnerText = "un valor"

在这里，它们可能是myWebBrowser，或者元素不存在。DocumentNothingformfld1

---

用户界面控件

Dim cmd5 As New SqlCommand("select Cartons, Pieces, Foobar " _
     & "FROM Invoice where invoice_no = '" & _
     Me.ComboBox5.SelectedItem.ToString.Trim & "' And category = '" & _
     Me.ListBox1.SelectedItem.ToString.Trim & "' And item_name = '" & _
     Me.ComboBox2.SelectedValue.ToString.Trim & "' And expiry_date = '" & _
     Me.expiry.Text & "'", con)

除其他事项外，此代码并未预期用户可能未在一个或多个控件中选择任何内容。 ListBox1.SelectedItem很可能是Nothing，所以它会ListBox1.SelectedItem.ToString导致 NRE。

解决方案

使用前验证数据（也推荐使用Option Strict和SQL参数）：

Dim expiry As DateTime         ' para validar un texto de una fecha    If (ComboBox5.SelectedItems.Count > 0) AndAlso
    (ListBox1.SelectedItems.Count > 0) AndAlso
    (ComboBox2.SelectedItems.Count > 0) AndAlso
    (DateTime.TryParse(expiry.Text, expiry) Then

    '... hacer cosas
Else
    MessageBox.Show(...mensaje de error...)
End If

或者，您也可以使用(ComboBox5.SelectedItem IsNot Nothing) AndAlso...

---

Visual Basic 窗体

Public Class Form1

    Private NameBoxes = New TextBox(5) {Controls("TextBox1"), _
                   Controls("TextBox2"), Controls("TextBox3"), _
                   Controls("TextBox4"), Controls("TextBox5"), _
                   Controls("TextBox6")}

    ' lo mismo en un formato diferente:
    Private boxList As New List(Of TextBox) From {TextBox1, TextBox2, TextBox3 ...}

    ' NRE Inmediato:
    Private unaVariable As String = Me.Controls("TextBox1").Text

这是获得 NRE 的一种非常常见的方式。在 C# 中，根据编程方式，IDE 会报告Controls它在当前上下文中不存在，或者“无法从静态范围访问非静态成员”。所以在某种程度上，这是一种只能在 VB 中发生的情况。这也是一个复杂的情况，因为它可能导致级联故障。

数组和集合不能以这种方式初始化。此初始化代码将在构造函数创建表单或控件（ ）之前Controls执行。因此：

• Las Listas y Colecciones estarán simplemente vacías
• El Array contendrá cinco elementos de Nothing
• La asignación a unaVariable resultará en una NRE inmediata, porque Nothing no tiene una propiedad .Text

Referenciar los elementos del array mas tarde resultará en una NRE. Si lo haces en el Form_Load, debido a un bug extraño, el IDE podría no reportar la excepción cuando ocurra. La excepción aparecerá mas tarde cuando tu código intent usar el array. Esta "excepción silenciosa" es detallada en este post (en inglés). Para nuestro propósito, la clave es que cuando algo catastrófico ocurre al crear un formulario (Sub New o evento Form Load), las excepciones podrían no reportarse. El flujo sale del procedimiento y simplemente muestra el formulario.

Dado que ningún código mas en tu Sub New o en tu evento Form Load se ejecutará después de la NRE, un montón de otras cosas podrían quedarse sin inicializar.

Sub Form_Load(..._
   '...
   Dim name As String = NameBoxes(2).Text        ' NRE
   ' ...
   ' Mas código (que probablemente no se ejecutará)
   ' ...
End Sub

Nota esto aplica para cualquiera y todas las referencias a controles y componentes haciendo esto ilegal donde se encuentre:

Public Class Form1

    Private myFiles() As String = Me.OpenFileDialog1.FileName & ...
    Private dbcon As String = OpenFileDialog1.FileName & ";Jet Oledb..."
    Private studentName As String = TextBox13.Text

Solución parcial

Es curioso que VB no de al menos un aviso, pero la solución es declarar los contenedores a nivel de formulario, pero inicializarles en el evento form load cuando los controles realmente existen. Esto se puede hacer también en Sub New siempre y cuando tu código esté después de la llamada a InitializeComponent:

' Declaración a nivel de módulo
Private NameBoxes as TextBox()
Private studentName As String

' Form Load, Form Shown or Sub New:
'
' (ilegal usando OPTION STRICT)
NameBoxes = New TextBox() {Me.Controls("TextBox1"), Me.Controls("TestBox2"), ...)
studentName = TextBox32.Text           

El código del array podría no estar a salvo todavía. Cualquier control que esté en un control contenedor (como un GroupBox o Panel) no se encontrará en Me.Controls; estarán en la colección Controls de ese Panel o GroupBox. Tampoco se devolverá ningun control si su nombre está mal escrito ("TeStBox2"). En esos casos, en esos elementos del array se almacenará Nothing y resultará en una NRE cuando intentes referenciarlos.

Estos deberían ser fáciles de encontrar ahora que ya sabes lo que estás buscando:

"Button2" está contenido en un Panel

Solución

En lugar de usar referencias indirectas por nombre usando la colección Controls del formulario, usa la referencia del control:

' Declaración
Private NameBoxes As TextBox()

' Inicializacion -  simple y fácil de leer, difícil de "chapucear":
NameBoxes = New TextBox() {TextBox1, TextBox2, ...)

' Inicializar una lista
NamesList = New List(Of TextBox)({TextBox1, TextBox2, TextBox3...})
' o
NamesList = New List(Of TextBox)
NamesList.AddRange({TextBox1, TextBox2, TextBox3...})

---

Function que devuelve Nothing

Private bars As New List(Of Bars)        ' Declarado y creado

Public Function BarList() As List(Of Bars)
    bars.Clear
    If someCondition Then
        For n As Integer = 0 to someValue
            bars.Add(GetBar(n))
        Next n
    Else
        Exit Function
    End If

    Return bars
End Function

Este es un caso donde el IDE mostrará un aviso de que 'no todas las rutas devuelve un valor lo que puede resultar en una NullReferenceException'. Puedes suprimir el aviso sustituyendo Exit Function con Return Nothing, pero eso no resuelve el problema. Cualquier cosa que intente usar el valor devuelto cuando someCondition = False resultará en una NRE:

bList = myFoo.BarList()
For Each b As Bar in bList      ' EXCEPCION
      ...

Solución

Cambia Exit Function en la función por Return bList. Devolver una lista(List) vacía no es lo mismo que devolver Nothing. Si existe la posibilidad de que un objeto devuelto pueda ser Nothing, compruébalo antes de usarlo:

 bList = myFoo.BarList()
 If bList IsNot Nothing Then...

---

Try/Catch mal implementado

Un Try/Catch mal implementado puede ocultar donde está el problema y provocar como consecuencia otros nuevos:

Dim dr As SqlDataReader
Try
    Dim lnk As LinkButton = TryCast(sender, LinkButton)
    Dim gr As GridViewRow = DirectCast(lnk.NamingContainer, GridViewRow)
    Dim eid As String = GridView1.DataKeys(gr.RowIndex).Value.ToString()
    ViewState("username") = eid
    sqlQry = "select FirstName, Surname, DepartmentName, ExtensionName, jobTitle,
             Pager, mailaddress, from employees1 where username='" & eid & "'"
    If connection.State <> ConnectionState.Open Then
        connection.Open()
    End If
    command = New SqlCommand(sqlQry, connection)

    'Mas código

    dr = command.ExecuteReader()
    If dr.Read() Then
        lblFirstName.Text = Convert.ToString(dr("FirstName"))
        ...
    End If
    mpe.Show()
Catch

Finally
    command.Dispose()
    dr.Close()             ' <-- NRE
    connection.Close()
End Try

Este caso es el de un objeto que no ha sido creado como se esperaba, pero también demuestra la "extrema" utilidad de un Catch vacío.

Hay una coma de más en el SQL (después de 'mailaddress') que causa una excepción en .ExecuteReader. Después de que Catch no haga nada, Finally intenta hacer limpieza, pero como no puedes cerrar(Close) un DataReader nulo, una nueva NullReferenceException es lanzada.

Un bloque Catch vacío es muy peligroso y nada recomendable. Este OP estaba sorprendido intentando entender porqué estaba obteniendo una NRE en el bloque Finally. En otras situaciones, un Catch vacío podría resultar en algo mucho mas grave y hacerte perder mucho tiempo probando cosas equivocadas en el lugar equivocado para encontrar el problema. (La "excepción silenciosa" descrita anteriormente proporciona el mismo entretenimiento añadido.)

Solución

No uses bloques Try/Catch vacios - deja que el código falle para que puedas a) identificar la causa b) indetificar la localización y c) aplicar la solución correcta. Los bloques Try/Catch no se hicieron para ocultar las excepciones de la persona cualificada para solucionarlas - el desarrollador.

---

DBNull no es lo mismo que Nothing

For Each row As DataGridViewRow In dgvPlanning.Rows
    If Not IsDBNull(row.Cells(0).Value) Then
        ...

La funciónIsDBNull se usa para comprobar si un valor es igual que System.DBNull: De MSDN:

El valor System.DBNull indica que el objeto representa datos que faltan o no existen. DBNull no es lo mismo que Nothing, que indica que una variable aun no ha sido inicializada.

Solución

If row.Cells(0) IsNot Nothing Then ...

Como antes, puedes comprobar primero Nothing, y después por un valor específico:

If (row.Cells(0) IsNot Nothing) AndAlso (IsDBNull(row.Cells(0).Value) = False) Then

Ejemplo 2

Dim getFoo = (From f In dbContext.FooBars
               Where f.something = something
               Select f).FirstOrDefault

If Not IsDBNull(getFoo) Then
    If IsDBNull(getFoo.user_id) Then
        txtFirst.Text = getFoo.first_name
    Else
       ...

FirstOrDefault devuelve el primer elemento o el valor por defecto, que en el caso de tipos de referencia es Nothing y nunca DBNull:

If getFoo IsNot Nothing Then...

---

Controles

Dim chk As CheckBox

chk = CType(Me.Controls(chkName), CheckBox)
If chk.Checked Then
    Return chk
End If

Si un CheckBox con chkName no se encuentra (o existe en un GroupBox), entonces chk será Nothing y el intento de referenciar cualquier propiedad resultará en una excepción.

Solución

If (chk IsNot Nothing) AndAlso (chk.Checked) Then ...

El DataGridView

El DGV tiene algunos "caprichos" que se ven periódicamente:

dgvBooks.DataSource = loan.Books
dgvBooks.Columns("ISBN").Visible = True       ' NullReferenceException
dgvBooks.Columns("Title").DefaultCellStyle.Format = "C"
dgvBooks.Columns("Author").DefaultCellStyle.Format = "C"
dgvBooks.Columns("Price").DefaultCellStyle.Format = "C"

Si dgvBooks tiene AutoGenerateColumns = True, creará las columnas pero no las pondrá nombre, así que el código de arriba falla cuando trata de referenciarlas por nombre.

Solución

Pon nombre a las columnas manualmente, o referéncialas por índice:

dgvBooks.Columns(0).Visible = True

Ejemplo 2 — Cuidado con NewRow

xlWorkSheet = xlWorkBook.Sheets("sheet1")

For i = 0 To myDGV.RowCount - 1
    For j = 0 To myDGV.ColumnCount - 1
        For k As Integer = 1 To myDGV.Columns.Count
            xlWorkSheet.Cells(1, k) = myDGV.Columns(k - 1).HeaderText
            xlWorkSheet.Cells(i + 2, j + 1) = myDGV(j, i).Value.ToString()
        Next
    Next
Next

Cuando tu DataGridView tiene AllowUserToAddRows a True (pro defecto), las Cells en la fila vacía/nueva al final contendrán todas Nothing. Los intentos de usar los contenidos de ésta (por ejemplo, ToString) resultarán en una NRE.

Solución

Usa un bucle For/Each y pregunta por la propiedad IsNewRow para determinar si es la última fila. Esto funciona aunque AllowUserToAddRows sea true o false:

For Each r As DataGridViewRow in myDGV.Rows
    If r.IsNewRow = False Then
         ' puedes usar esta fila

Si usas un bucle For n, modifica el contador de filas o usa Exit For cuando IsNewRow es true.

---

My.Settings (StringCollection)

Bajo ciertas circunstancias, intentado usar un elemento de My.Settings que es un StringCollection puede resultar en una NullReference la primera vez que lo usas. La solución es la misma, aunque no tan obvia. Considera:

My.Settings.FooBars.Add("ziggy")         ' foobars es una string collection

Ya que VB está gestionando Settings por ti, es razonable esperar que inicialice la colección. Lo hará, pero solo si previamente has añadido un elemento inicial a la colección (en el editor de Settings). Ya que la colección esta siendo (aparentemente) inicializada cuando un elemento es añadido, permanece a Nothing cuando no hay elementos en el editor de Settings para añadir.

Solución

Inicializa la colección de settings en el manejador del evento Load del formulario, si es necesario:

If My.Settings.FooBars Is Nothing Then
    My.Settings.FooBars = New System.Collections.Specialized.StringCollection
End If

通常，该集合Settings只需要在应用程序第一次运行时进行初始化。另一种解决方案是在Project -> Settings |中为集合添加初始值。FooBars，保存项目，然后删除 false 值。

---

关键点

您可能忘记了操作员New。

任何一个

您认为可以完美返回已初始化对象的东西没有。

不要忽略编译器警告（从不）并使用Option Strict On（总是）。

---

MSDN 类 NullReferenceException

---

这个答案是这个Stack Overflow答案的翻译