Home / Questions / 9748
Accepted
Jose Dario Correa
Asked: 2020-05-13 06:55:16 +0800 CST 2020-05-13 06:55:16 +0800 CST

Merge cells in DataGridView VB.NET

  • 772

The question I have is, how can I combine cells in a DataGridView?

In my VB.NET project I have a DataGridView that displays information from a table in my MySQL database as follows:

enter image description here

And what I want is to combine the cells of the first column so that it looks something like this:

enter image description here

How do I do it?

The tables in the images are made in Excel just to give an example, it should be clarified that I only show 2 services but in reality there are 30 services.

vb.net

3 Answers

  1. The DataGridView does not provide this functionality.

    In CodeProject if you can find an implementation of a column type for DataGridView that allows to do it:

    DataGridVewTextBoxCell with Span Behavior

    It basically creates a column type DataGridViewTextBoxColumnEx whose cells are of type DataGridViewTextBoxCellEx. These cells allow you to combine cells through their RowSpan and ColSpan properties.

    An example of use:

        DataGridView1.Rows.Add("Bath/Shower", "Turn 1")
    DataGridView1.Rows.Add("Bath/Shower", "Turn 2")
    DataGridView1.Rows.Add("Bath/Shower", "Turn 3")
    DataGridView1.Rows.Add("Hair Care", "Turn 1")
    DataGridView1.Rows.Add("Hair Care", "Turn 2")
    DataGridView1.Rows.Add("Hair Care", "Turn 3")
    Dim cell As DataGridViewTextBoxCellEx = CType(DataGridView1(0, 0), DataGridViewTextBoxCellEx)
    cell.RowSpan = 3
    cell = CType(DataGridView1(0, 3), DataGridViewTextBoxCellEx)
    cell.RowSpan = 3

    The result:

    enter image description here

    To use it:

    1. Download the project code from the CodeProject website
    2. The code is a solution with 3 projects. The one you are interested in is SpannedDataGridViewNet2. Add this project to your solution
    3. In your Windows Forms project add a reference to this project and compile
    4. When adding columns in your DataGridView you will have the option to choose a new column type: DataGridViewTextBoxColumnEx
    5. The cells of these columns are of the DataGridViewTextBoxCellEx type that allow you to indicate values ​​for their RowSpan and ColumnSpan properties as I put in the example
    • 2

  2. You could choose an option like being

    How to Merge DataGridView Cell in Winforms

    in the event CellPaintingof the DataGridView

    there it validates if the value of the column is equal to that of the previous cell, if it is, it eliminates the line of the cells using

     e.AdvancedBorderStyle.Top = DataGridViewAdvancedCellBorderStyle.None;

    There is also another more complex way that uses GDI

    MERGING CELLS IN DATAGRIDVIEW

    • 1
  3. Best Answer

    This is the perfect solution to my problem, I share it for everyone to have.

    The following instruction is placed in the Load event of the Form :

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    DataGridView1.AutoGenerateColumns = False
End Sub

    In the CellPainting event of the DataGridView we place the following:

    Private Sub DataGridView1_CellPainting(sender As Object, e As DataGridViewCellPaintingEventArgs) Handles DataGridView1.CellPainting
    e.AdvancedBorderStyle.Bottom = DataGridViewAdvancedCellBorderStyle.None
    If (e.RowIndex < 1 Or e.ColumnIndex < 0) Then
        Return
    End If

    If (IsTheSameCellValue(e.ColumnIndex, e.RowIndex)) Then
        e.AdvancedBorderStyle.Top = DataGridViewAdvancedCellBorderStyle.None
    Else
        e.AdvancedBorderStyle.Top = DataGridView1.AdvancedCellBorderStyle.Top
    End If
End Sub

    In the CellFormatting event of the DataGridView we place the following:

    Private Sub DataGridView1_CellFormatting(sender As Object, e As DataGridViewCellFormattingEventArgs) Handles DataGridView1.CellFormatting
    If (e.RowIndex = 0) Then
        Return
    End If
    If (IsTheSameCellValue(e.ColumnIndex, e.RowIndex)) Then
        e.Value = ""
        e.FormattingApplied = True
    End If
End Sub

    And additionally we need to create a function:

    Private Function IsTheSameCellValue(ByVal column As Integer, ByVal row As Integer) As Boolean
    Dim cell1 As DataGridViewCell = DataGridView1(column, row)
    Dim cell2 As DataGridViewCell = DataGridView1(column, row - 1)
    If (IsDBNull(cell1.Value) Or IsDBNull(cell2.Value)) Then
        Return False
    End If
    If (cell1.Value = cell2.Value) Then
        Return True
    Else
        Return False
    End If
End Function
    • 1