Home / Questions / 546936
Accepted
Magali
Asked: 2022-07-18 18:51:50 +0800 CST 2022-07-18 18:51:50 +0800 CST

How can I count the number of columns in an ascending order of a matrix? I am using pascal

  • 772
procedure ascendentes(n,m: byte ; mat: tipomat); 
var
i,j,suma: byte ;
  
  
  begin
    suma:=0;
    i:=2; 
  for j:=1 to m do 
     begin
       while (i<=n) and (mat[i,j]>mat[i-1,j]) do
         begin
           i:= i+1;
           suma:= suma+1;
         end;
     end; 
        writeln(i,'...',suma);
  if i> n then 
      writeln('cumple con ',suma)
  else
      writeln('no cumple ');
  end;

// It doesn't calculate the number of columns correctly. I'm using pascal

pascal

1 Answers

  1. Best Answer

    The problem you have is that you have not yet developed the logic that correctly solves the problem. My advice is that, considering how a program works, solve the problem first using paper and pencil.

    One way I can think of is to declare a boolean variable EsAscendenteand, for each column, start by assuming it is ascending and go through it row by row. If a case is found where the cell of the current row is not greater than the cell of the previous row, set this variable to false and abort the cycle that goes through the rows (it is not necessary to see more rows, it is already known that the column is not ascending).

    At the end of this cycle, if the variable EsAscendentehas a true value, we increment the variable by one Contadorand proceed to the next column.

    I've made an example with a couple of constants and an array type called TMatriz:

    const
  NumFilas = 5;
  NumColumnas = 5;
type
  TMatriz = array[1..NumFilas, 1..NumColumnas] of Integer;

procedure ContarColumnasAscendentes(const AMatriz: TMatriz);
var
  Fila, Columna: Integer;
  Contador: Integer;
  EsAscendente: Boolean;
begin
  Contador := 0;
  for Columna := 1 to NumColumnas do
  begin
    EsAscendente := True;
    for Fila := 2 to NumFilas do
      if AMatriz[Fila, Columna] <= AMatriz[Fila - 1, Columna] then
      begin
        EsAscendente := False;
        Break;
      end;
    if EsAscendente then Inc(Contador);
  end;
  Writeln;
  Writeln('La matriz tiene ', Contador, ' columnas en orden ascendente');
end;

    Running my full example, I get output like the following:

    Matriz:
   1   2   5   3  20
   2   4   4   6  19
   3   6   3   9  18
   4   8   2  12  17
   5  10   1  15  16

La matriz tiene 3 columnas en orden ascendente
    • 1