Home / Questions / 492862
Accepted
Jessica567
Asked: 2022-03-26 06:36:32 +0800 CST 2022-03-26 06:36:32 +0800 CST

Haskell - Function with 2 conditionals and output of a tuple does not return correct value

  • 772

I have the following function developed in Haskell, it performs an avg of 3 entered notes and depending on the condition it counts the elements of the list (using length), the first output of the tuple should be count( ) when the condition >= 4 and the second count( ) when it is < 4:

funcion1::[(String, Int,Int,Int)]->(Int,Int)
funcion1 ((nombre,nota1,nota2,nota3):xs) = ( if (nota1+nota2+nota3) `div` 3 >=4 then 1 + funcion1 xs else funcion1 xs ,
                                             if (nota1+nota2+nota3) `div` 3 <4 then 1 + funcion1 xs else funcion1 xs )

However, when entering data in the input, the tuple always returns the same values ​​for both cases (Example: When entering 3 elements with avg >= 4 and only 1 with avg < 4, the output should be (3,1) and currently it is ( 3.3).

lista

1 Answers

  1. Best Answer

    You misunderstand the problem. Haskell doesn't use if/else as much as it does in other languages. When working with lists you have to think more about applying filters ( filter) and other functions that support predicates (what you say conditionals ).

    funcion1 :: [(String, Int, Int, Int)] -> (Int, Int)
funcion1 xs = (length $ filter (>=4) avgs, length $ filter (<4) avgs)
  where
    avg (_, nota1, nota2, nota3) = (nota1 + nota2 + nota3) `div` 3
    avgs = map avg xs

    We have created the function avgthat calculates the mean and we have applied it to obtain a list of means avgs. Two filters are applied to this list, (>=4)and (<4), to obtain the two sublists whose lengths will give us the count we are looking for.

    Since the two filters are mutually exclusive (the elements that meet one filter do not meet the other), what we really have is a partition of the list and we can make it a little simpler by applying the function partitionof the module Data.List:

    import Data.List (partition)

funcion1 :: [(String, Int, Int, Int)] -> (Int, Int)
funcion1 xs = ( (length . fst) part, (length . snd) part)
  where
    avg (_, nota1, nota2, nota3) = (nota1 + nota2 + nota3) `div` 3
    avgs = map avg xs
    part = partition (>=4) avgs

    All that remains is to make it beautiful by creating a function maptupleto make a map in a tuple:

    import Data.List (partition)

funcion1 :: [(String, Int, Int, Int)] -> (Int, Int)
funcion1 xs = maptuple length part
  where
    avg (_, nota1, nota2, nota3) = (nota1 + nota2 + nota3) `div` 3
    avgs = map avg xs
    part = partition (>=4) avgs
    maptuple f (a,b) = (f a, f b)

    Even prettier yet, putting it all together:

    import Data.List (partition)

funcion1 :: [(String, Int, Int, Int)] -> (Int, Int)
funcion1 = maptuple length . partition (>=4) . map avg
  where
    avg (_, nota1, nota2, nota3) = (nota1 + nota2 + nota3) `div` 3
    maptuple f (a,b) = (f a, f b)
    • 0