Home / Questions / 487542
Accepted
JAACH_TAG
Asked: 2022-09-30 15:19:39 +0800 CST 2022-09-30 15:19:39 +0800 CST

How to insert an element in the middle of a Prolog list?

  • 772

I have searched for information on the net, regarding how to insert an element in the middle of a list in Prolog, but I have not found relevant information regarding what I want to do.

%Create_a_program_in_Prolog_that_inserts_an_element_in_the_half_of_a_list %insert_half([a,b,c,d,e,f],x,R). %R=[a,b,c,x,d,e,f].

I am new to using the Prolog program and learning its logic. Also, I'm honest, it's a university exercise and I don't know how to do it, thanks in advance

lista

2 Answers

  1. Best Answer

    To insert in the middle of a list you can traverse the list at two "speeds": one advancing one element at a time and the other advancing two elements at a time.

    This way when you get to the end of the second list the first will be in the middle. At that point you can add the item you want in the middle along with the other half of the list.

    insertar_mitad(L, E, R):-
  insertar_mitad(L, L, E, R).
  
insertar_mitad([], L, E, [E|L]).
insertar_mitad([_], L, E, [E|L]).
insertar_mitad([_, _|L], [Item|L2], E, [Item|R]):-
  insertar_mitad(L, L2, E, R).

    The second clause of insert_half/4 covers the case of lists of odd number. If the procedure is removed it will only happen for lists of even number of elements.

    Test cases:

    ?- insertar_mitad([a,b,c,d,e,f],x,R).
R = [a, b, c, x, d, e, f].

?- insertar_mitad([a,b,c,d,e,f,g],x,R).
R = [a, b, c, x, d, e, f, g] ;
false.

    To avoid leaving alternatives, another auxiliary procedure can be added to help indexing:

    insertar_mitad(L, E, R):-
  insertar_mitad(L, L, E, R).
  
insertar_mitad([], L, E, [E|L]).
insertar_mitad([_|L], L2, E, R):-
  insertar_mitad1(L, L2, E, R).

insertar_mitad1([], L, E, [E|L]).
insertar_mitad1([_|L], [Item|L2], E, [Item|R]):-
  insertar_mitad(L, L2, E, R).

    In which we now see that the second example leaves no alternatives:

    ?- insertar_mitad([a,b,c,d,e,f],x,R).
R = [a, b, c, x, d, e, f].

?- insertar_mitad([a,b,c,d,e,f,g],x,R).
R = [a, b, c, x, d, e, f, g].
    • 2 
  2. %caso base de insertar
insertar(E,L,1,[E|L]).
%caso recursivo
insertar(E,[Ca|Resto],Pos,[Ca|R]):-
   Pos>1, Pos1 is Pos-1,
   insertar(E,Resto,Pos1,R).

%caso base de longitud
longitud([],0).
longitud([Ca|Resto], N1):-
  longitud(Resto,N),
  N1 is N+1.

%insertar en la mitad
insertar_mitad(L,E,R):-
  longitud(L,N),
  N2 is div(N+1,2)+1,
  insertar(E,L,N2,R).
    • 0