Home / Questions / 454618
Accepted
Leandro Palavecino
Asked: 2022-05-25 13:00:32 +0800 CST 2022-05-25 13:00:32 +0800 CST

Using object from class with Delphi

  • 772

I'm learning and there are things I don't understand. I was reading documentation about creating classes and constructors etc. But I can't understand how it works for what I need. I know that it is something basic and that I am not understanding, let me explain:

I need to create the Dog object from the class TDOG and use it independently as a container to make modifications to it, before assigning it back to the array containing a collection of dogs. But when assigning to the variable DOG , the object vector[i]of the same class, to be able to edit it and later save it in the vector, it is as if any modification in the dog variable, immediately modifies the position of the vector.

    type
    Tperro = class
    nombre : string;
    raza : string;
end

var
vector : array [1..10] of TPerro;

implementation

procedure Tform1.cargarperros; //cargo los perros
    begin
    vector[1]:= TPerro.create
    vector[1].nombre := 'Cubo';
    vector[1].raza := 'caniche';

    vector[2]:= TPerro.create;
    vector[2].nombre :='Chopper';
    vector[2].raza := 'labrador';
end;

procedure TForm1.edicion; // editar Perro, utilizando el objeto "PERRO" y no directamente desde el vector
var perro : TPerro;
begin

Perro := TPerro.create;
Perro := vector[1]; //asigno los datos de vector[1] a variable PERRO

Perro.name := 'Olmedo'; 
Showmessage('Nombre anterior ' + vector[1].name); //aca el nombre sale "olmedo" (cuando deberia salir "CUBO")
Showmessage('Nombre Nuevo ' + Perro.name); //aca sale nombre "olmedo"

vector[1] := Perro //aca vuelvo al vector, y le asigno las modificaciones en el (recipiente) PERRO.

end;

The showmessage( which I use to show you what happens to me ) shows the same thing for both DOG , and for vector[1], when in fact I need that the vector that contains the collection of dogs, not be previously modified, without first verifying the DOG object , to which I make the modifications.

I remember that before using the class ( record ) I did not have these problems. But since I need to add methods to the TPerro class , I need to use it as an Object and not as a record. I don't know if you can add methods to the record class though . Still, I'm learning and need to understand how it works.

Any change you make to the DOG object is made immediately to the array position you previously assigned to it. ( PERRO := vector[1]). Is there something I'm not understanding, or I don't know if I'm missing something, or I should declare the constructor method of the class with some kind of specification.
I hope to explain myself well.

delphi

1 Answers

  1. Best Answer

    In Delphi all objects are created in the memory area called heap (heap, in Spanish) and what you save, when you make an assignment to an object type variable is a reference , also known as a pointer to the memory address where it resides the object.

    I recommend you read. If you don't have a good Pascal programming book, google, for example pascal pointers .

    When you do this:

    Perro := TPerro.create;
Perro := vector[1]; //asigno los datos de vector[1] a variable PERRO

    In the first line, you create a new instance of TPerroand assign to the variable Perrothe memory address where this new instance has been created. It is said that it now Perro points to the new instance of TPerro.

    In the second line, there is NOT an assignment of the values ​​that are stored in the members of the dog pointed vector[1]to by this new dog instance, as you are assuming, but what happens is that now the variable Perropoints to the same address where it points to vector[1]and any changes you make will be reflected in both (since they both point to the same object, which exists only once in memory.

    The basic test that is normally done to exemplify this is with two variables, for example:

    procedure TForm1.Prueba;
var
  PerroA, PerroB: TPerro;
begin
  PerroA := TPerro.Create();
  try
    PerroA.Nombre := 'Colocho';
    PerroA.Raza := 'Cocker';
    PerroB := PerroA;  //ambos apuntan al mismo objeto;
    ShowMessage(PerroB.Nombre);
    PerroB.Nombre := 'Gangster';
    ShowMessage(PerroA.Nombre);
  finally
    PerroA.Free;
    //después de este punto, PerroA y PerroB apuntan a una 
    //dirección de memoria donde ya no existe el objeto, 
    //no deben utilizarse y si se utilizan el comportamiento es indefinido.
  end;
end;

    Regardless of the memory size of an object, the variable used to access it will have a fixed size (4 bytes in 32-bit applications and 8 bytes in 64-bit applications).

      ShowMessage(IntToStr(SizeOf(vector)));

    It will show 40 if you build your app for 32-bit platforms and 80 if you build your app for 64-bit platforms.

    If you want the new variable Perroto have a copy of the values ​​contained in the object it points to vector[1], you have to go member by member, for example:

    procedure TForm1.edicion; 
var 
  perro : TPerro;
begin
  Perro := TPerro.create;
  try
    Perro.Nombre := vector[1].Nombre; 
    Perro.Raza := vector[1].Raza;
    Perro.Nombre := 'Olmedo'; 
    Showmessage('Nombre anterior ' + vector[1].Nombre); 
    Showmessage('Nombre Nuevo ' + Perro.Nombre); 

    Vector[1].Nombre := Perro.Nombre;
    Vector[1].Raza := Perro.Raza; 
  finally
    Perro.Free;
  end;
end;

    If you look at my code, you'll notice that I'm careful to always release the objects I create. This prevents memory leaks (also known as memory leaks ), since there is no garbage collector in Delphi and it is the responsibility of the programmer to ensure that resources that are no longer used are returned to the system.

    It only remains for me to explain the difference you see with the behavior of registers, and this is because registers are not pointers, but merely value containers that behave like other primitive data types, say an integer. When a local variable of type register is declared, the space for the entire structure is reserved on the stack (the stack) and not on the heap (as in the case of objects).

    If you want to create records on the heap , you must use pointer operators, such as ^and @, in addition to the New()and functions Dispose()to manage their memory, for example:

    program Project1;

{$APPTYPE CONSOLE}

type
  TMiRegistro = record
    Numeros: array[1..100] of Integer;
    Cadenas: array[1..100] of string;
  end;
  PMiRegistro = ^TMiRegistro;

  TMiObjeto = class
    Numeros: array[1..100] of Integer;
    Cadenas: array[1..100] of string;
  end;

var
  Reg: TMiRegistro;
  PReg: PMiRegistro;
  Obj: TMiObjeto;
begin
  Writeln('Reg:  ', SizeOf(Reg));
  Writeln('PReg: ', SizeOf(PReg));
  Writeln('Obj:  ', SizeOf(Obj));
  ReadLn;
end.

    This program, compiled for 32-bit, produces the output:

    Reg:  800
PReg: 4
Obj:  4
    • 2