How to improve a macro that copies cell values?

Let's totally change the logic of your process to clearly understand what to do in each case...

First, instead of iterating a range, since there are rows that are not processed, we are going to do the following:

Let UltimaFila = Cells(Rows.Count, 10).End(xlUp).Row
dim i as int = 3
while (i < UltimaFila)
    ....
end while

Now, inside the while, let's check each of the conditions, in order...

''caso 1
if range("J" & i).value <> "" and range("K" & i).value <> "" then
    ''aca copiamos los valores segun corresponde, a las celdas que queremos
    range("F" & (i+1)).value = range("J" & i).value
    range("F" & (i+2)).value = range("K" & i).value
    ..si hay mas copias...
    ''y ahora, aumentamos i a la siguiente linea a procesar
    i = i + 3
''caso 2
else if(range("K" & i).value <> "") then
    .... hacemos las copias...
    ''aumentamos i
    i = i +2
else
    ''caso 3
    
end if

Note that I wrote you the logic that you have to use for each case... try it, follow it and anything we update the answer.

Your fundamental problem is to identify when it is case 1, 2, 3 or 4. But luckily, you have identified each case in the last column.

The macro should read that column, and depending on whether it is 1, 2, 3 or 4, proceed one way or another.

The downside is that those cells are merged. When the cells are combined, only the first of the set has a value, the others are actually empty. So you have to access the combined area ( MergeArea) and within that area, always study the first cell, which is the one with the value (the first cell of a range is alwaysCells(1,1)

Knowing this, I have designed a code that does each case individually. If he sees that a merged area has already been surveyed, he ignores it and moves on to the next row.

Here is how it works:

And the code:

Sub test()
Application.ScreenUpdating = False
Dim i As Long
Dim UF As Long
Dim AreaEstudiada As String

UF = Range("A" & Rows.Count).End(xlUp).Row

For i = 3 To UF Step 1 'tus datos empiezan en fila 3 según ejemplo
    If AreaEstudiada = Range("P" & i).MergeArea.Address Then
        'este caso ya ha sido estudiado, no hago nada
    Else
        AreaEstudiada = Range("P" & i).MergeArea.Address
        Select Case UCase(Range("P" & i).MergeArea.Cells(1, 1).Value)
            Case "CASO 1"
            'se deben copiar en la columna F en los espacios disponibles debajo de la celda con valor;
            'por ejemplo si las celdas J3 y K3 tienen un valor numerico se debe copiar el valor de celda
            'en las celdas F4 y F5 respectivamente. *Cuando las celdas de las columnas M y N tengan un registro,
            'se deben copiar en la columna G en los espacios disponibles debajo de la celda con valor;
            'por ejemplo si las celdas M3 y N3 tienen un valor numerico se debe copiar el valor de celda en las celdas G4 y G5 respectivamente.
                Range("F" & i + 1).Value = Range("J" & i).Value
                Range("F" & i + 2).Value = Range("K" & i).Value
                Range("G" & i + 1).Value = Range("M" & i).Value
                Range("G" & i + 2).Value = Range("N" & i).Value
            Case "CASO 2"
            'Cuando la celda de la columnas K tenga un registro, se deben copiar en la columna F
            'en el espacios disponible debajo de la celda con valor; por ejemplo si las celdas K6
            'tiene un valor numerico se debe copiar el valor de celda en la celda F7. *Cuando la celda
            'de la columna N tengan un registro, se deben copiar en la columna G en el espacio disponible
            'debajo de la celda con valor; por ejemplo si la celda N6 tiene un valor numerico se debe copiar el valor de celda en la celda G7.
                Range("F" & i + 1).Value = Range("K" & i).Value
                Range("G" & i + 1).Value = Range("N" & i).Value
            Case "CASO 3"
            'Cuando la celda de la columnas J tenga un registro, se deben copiar en la columna F en el
            'espacios disponible debajo de la celda con valor; por ejemplo si las celdas J8 tiene un
            'valor numerico se debe copiar el valor de celda en la celda F9. *Cuando la celda de la
            'columna M tengan un registro, se deben copiar en la columna G en el espacio disponible
            'debajo de la celda con valor; por ejemplo si la celda M8 tiene un valor numerico se debe copiar el valor de celda en la celda G9.
                Range("F" & i + 1).Value = Range("J" & i).Value
                Range("G" & i + 1).Value = Range("M" & i).Value
            Case "CASO 4"
                ' la macro no debe copiar valores, debe omitir
                'no hacemos nada
            Case Else
                MsgBox "ERROR, CASO NO CONTEMPLADO", vbCritical
                End
        End Select
    End If
Next i
Application.ScreenUpdating = True

End Sub

UPDATE: Since the P column cannot be used, what I have done is try to establish a mathematical relationship between the IDs and the cases.

If you look, according to your example, the IDs that are repeated 3 times are case 1. Those that are repeated 1 time are case 4. And those that are repeated 2 times can be case 2 or 3, depending on whether the columns J and M are empty or not.

On that mathematical basis, I have modified the original code. What has been done has been to incorporate a dictionary.

Dictionaries in VBA

With this object, I can store unique values ​​and assign a value to them. That is, I am pointing to each of the IDs in column C, and assigning them if they are Case 1, 2, etc.

Then it's pretty much the same loop as before. This is the code:

Sub test()
Application.ScreenUpdating = False

Dim MiDict As Object
Set MiDict = CreateObject("Scripting.Dictionary")

Dim i As Long
Dim UF As Long

UF = Range("A" & Rows.Count).End(xlUp).Row

'primero, analizamos todos los ID de la columna C. Tenemos que asociar a cada ID uno de los 4 casos posibles.

For i = 3 To UF Step 1 'tus datos empiezan en fila 3 según ejemplo
    'primero comprobamos si ese ID existe en el diccionario
    
    If MiDict.Exists(Range("C" & i).Value) = False Then
        'no existe. Estudio que caso es y lo guardo en el diccionario
        If Application.WorksheetFunction.CountIf(Range("C" & 3 & ":C" & UF), Range("C" & i).Value) = 3 Then
            'si el ID existe 3 veces, es caso 1
            MiDict.Add Range("C" & i).Value, "CASO 1"
        ElseIf Application.WorksheetFunction.CountIf(Range("C" & 3 & ":C" & UF), Range("C" & i).Value) = 1 Then
            'si el ID existe 1 sola vez, entonces es caso 4.
            MiDict.Add Range("C" & i).Value, "CASO 4"
        ElseIf Application.WorksheetFunction.CountIf(Range("C" & 3 & ":C" & UF), Range("C" & i).Value) = 2 Then
            'existe 2 veces, pero tenemos que ver si es caso 2 o 3
            'es caso 2 si J y M están vacías
            If Range("J" & i).Value = "" And Range("M" & i).Value = "" Then
                MiDict.Add Range("C" & i).Value, "CASO 2"
            Else
                MiDict.Add Range("C" & i).Value, "CASO 3"
            End If
        Else
            'si existe una cantidad de veces diferente a 1, 2 o 3, es un caso diferente, no desarrollado.
            MsgBox "ERROR;CASO NO DETECTADO", vbCritical
            End
        End If
    End If
Next i

'ya tenemos los casos estudiados. ahora buscamos cada id en el diccionario. La primera vez haremos su proceso, y lo marcaremos como completado.
'la segunda vez que mire ese ID, como está marcado como completado, lo ignorará


For i = 3 To UF Step 1 'tus datos empiezan en fila 3 según ejemplo

    Select Case UCase(MiDict(Range("C" & i).Value))
        Case "CASO 1"
        'se deben copiar en la columna F en los espacios disponibles debajo de la celda con valor;
        'por ejemplo si las celdas J3 y K3 tienen un valor numerico se debe copiar el valor de celda
        'en las celdas F4 y F5 respectivamente. *Cuando las celdas de las columnas M y N tengan un registro,
        'se deben copiar en la columna G en los espacios disponibles debajo de la celda con valor;
        'por ejemplo si las celdas M3 y N3 tienen un valor numerico se debe copiar el valor de celda en las celdas G4 y G5 respectivamente.
            Range("F" & i + 1).Value = Range("J" & i).Value
            Range("F" & i + 2).Value = Range("K" & i).Value
            Range("G" & i + 1).Value = Range("M" & i).Value
            Range("G" & i + 2).Value = Range("N" & i).Value
        Case "CASO 2"
        'Cuando la celda de la columnas K tenga un registro, se deben copiar en la columna F
        'en el espacios disponible debajo de la celda con valor; por ejemplo si las celdas K6
        'tiene un valor numerico se debe copiar el valor de celda en la celda F7. *Cuando la celda
        'de la columna N tengan un registro, se deben copiar en la columna G en el espacio disponible
        'debajo de la celda con valor; por ejemplo si la celda N6 tiene un valor numerico se debe copiar el valor de celda en la celda G7.
            Range("F" & i + 1).Value = Range("K" & i).Value
            Range("G" & i + 1).Value = Range("N" & i).Value
        Case "CASO 3"
        'Cuando la celda de la columnas J tenga un registro, se deben copiar en la columna F en el
        'espacios disponible debajo de la celda con valor; por ejemplo si las celdas J8 tiene un
        'valor numerico se debe copiar el valor de celda en la celda F9. *Cuando la celda de la
        'columna M tengan un registro, se deben copiar en la columna G en el espacio disponible
        'debajo de la celda con valor; por ejemplo si la celda M8 tiene un valor numerico se debe copiar el valor de celda en la celda G9.
            Range("F" & i + 1).Value = Range("J" & i).Value
            Range("G" & i + 1).Value = Range("M" & i).Value
        Case "CASO 4"
            ' la macro no debe copiar valores, debe omitir
            'no hacemos nada
        Case Else
            'significa que es un caso ya estudiado. No hacemos nada
    End Select
    
    MiDict(Range("C" & i).Value) = "CASO ESTUDIADO"
Next i

MiDict.RemoveAll
Set MiDict = Nothing

Application.ScreenUpdating = True

End Sub

try with

Let LastRow = Cells(Rows.Count, 10).End(xlUp).Row dim i i = 3 Do while (i < LastRow)

'Here are the conditional cases that @gbianchi gives you

loop