How do I capture data from a SqlDataReader that is in a class into a function?

There are 2 very serious and fundamental problems in the current design you have that the other answers haven't mentioned:

1. You are using global variables for the connection and the SqlDataReader.
2. You're closing the connection ( desconectar()) before returning the SqlDataReader, so when you try to read the data with the SqlDataReader, it's going to throw you exceptions.

Time after time I am seeing questions where this pattern of using global connections is being used. This is very bad practice and will cause problems in more serious programs. There is nothing wrong with centralizing the code that opens the connection. But it is not correct to save the connection in a global variable.

And the problem with the second point is that in order to return a SqlDataReaderand be able to continue using it, the connection must be left open. But if you remove the call desconectar()from your method to fix this problem, your code now becomes even more brittle than it already is, because it's not very clear who has responsibility for closing the connection.

Here is a much more solid and reusable pattern that you can use to read the data from a SqlDataReaderfor any query and that does not fall into the design problems mentioned above.

For the example that I share with you, I am going to assume that instead of having a method conectar()that opens a connection and assigns it to a global variable (to avoid), I am going to assume that you have defined a method CrearConexionthat simply returns a new instance of SqlConnectionwithout assigning it to a global variable (correct). Something like:

Public Function CrearConexion() As SqlConnection
    Return New SqlConnection("<cadena de conexión>")
End Function

Method EjecutarLeerConsulta:

Public Sub EjecutarLeerConsulta(
    sql As String,
    leerRegistro As Action(Of SqlDataReader),
    ParamArray parametros As SqlParameter())

    Using conn As SqlConnection = CrearConexion()
        Using cmd = New SqlCommand(sql, conn)
            cmd.Parameters.AddRange(parametros)
            conn.Open()

            Using reader As SqlDataReader = cmd.ExecuteReader()
                While (reader.Read())
                    leerRegistro(reader)
                End While
            End Using
        End Using
    End Using
End Sub

With this method, you can execute and read any query using best practices, without global variables, without having to worry about when to open and close the connection, etc. Everything is handled automatically in this central method.

How to use it

To use the method, you need to pass at least 2 parameters to it:

• The SQL string.
• A lambda expression that defines the code to be executed for each record returned by the query.
• (Optional) A list of parameters ( SqlParameter) if the query requires them.

Example:

EjecutarLeerConsulta(
    "select * from persona",
    Sub(reader)
        Dim nombre As String = reader("nombre")
        Dim apellido As String = reader("apellido")
        ' agrega código aquí que asigna los valores a los TextBox o lo que quieras.
    End Sub)

And if you need to build queries with parameters, the call would look like this:

EjecutarLeerConsulta(
    "select * from persona where nombre = @nombre and apellido = @apellido",
    Sub(reader)
        Dim nombre As String = reader("nombre")
        Dim apellido As String = reader("apellido")
        ' agrega código aquí que asigna los valores a los TextBox o lo que quieras.
    End Sub,
    New SqlParameter("@nombre", "John"),
    New SqlParameter("@apellido", "Smith"))

Well, first I recommend that you add the type that you are going to return to the method at the end. Thus:

Function consulta() As SQLDataReader
End Function

now to get the data from the data reader you do it this way

'Llamas a tu función para obtener el lector de datos
Dim l = consulta()
'Evaluas si tiene columnas
If l.HasRows Then
    'Evaluas si se leyerón los datos. NOTA: Esto es en caso que solo sea una
    'fila que vas a leer, si son varias te recomiendo usar While l.Read()

    If l.Read() Then
        'obtienes los datos y los agregas donde mayor te convenga

        TextBox1.Text = l["Dato1"].ToString()
        TextBox2.Text = l["Dato2"].Tostring()
        Label1.Text = l["Dato3"].ToString()
        Label2.Text = l["Dato4"].ToString()
        Dim dato5 As Integer = Integer.Parse(l["Dato5"].ToString())

        '....... etc
    End If
End If

It uses the SQLDataReader class, in c# you can call it by index or by column name as follows

 NombreTextBox.Text = VariableDataReader["NombreColumna"].ToString();